| ASP开发中存储过程应用全接触 |
|
来源：互联网 |
时间：2006-04-05 |
浏览：
相关评论 |
报告错误 |
发布文章
|
【字号：大 | 中 | 小】
【背景色 
 】
|
|
)**
DIM MyComm,UserID,UserName
UserID = 1
Set MyComm = Server.CreateObject("ADODB.Command")
with MyComm
.ActiveConnection = MyConStr ’MyConStr是数据库连接字串
.CommandText = "getUserName" ’指定存储过程名
.CommandType = 4 ’表明这是一个存储过程
.Prepared = true ’要求将SQL命令先行编译
.Parameters.append .CreateParameter("@UserID",3,1,4,UserID)
.Parameters.append .CreateParameter("@UserName",200,2,40)
.Execute
end with
UserName = MyComm(1)
Set MyComm = Nothing
假如我们要取得ID为1到10，10位用户的用户名，是不是要创建10次Command对象呢？不是的。如果需要多次调用同一存储过程，只需改变输入参数，就会得到不同的输出：
’**多次调用同一存储过程**
DIM MyComm,UserID,UserName
UserName = ""
Set MyComm = Server.CreateObject("ADODB.Command")
for UserID = 1 to 10
with MyComm
.ActiveConnection = MyConStr ’MyConStr是数据库连接字串
.CommandText = "getUserName" ’指定存储过程名
.CommandType = 4 ’表明这是一个存储过程
.Prepared = true ’要求将SQL命令先行编译
if UserID = 1 then
.Parameters.append .CreateParameter("@UserID",3,1,4,UserID)
.Parameters.append .CreateParameter("@UserName",200,2,40)
.Execute
else
’重新给入参赋值(此时参数值不发生变化的入参以及出参不必重新声明)
.Parameters("@UserID") = UserID
.Execute
end if
end with
UserName = UserName + MyComm(1) + "," ’也许你喜欢用数组存储
next
Set MyComm = Nothing
通过以上代码可以看出：重复调用同一存储过程时，只需为值发生改变的输入参数重新赋值即可，这一方法在有多个输入输出参数，且每次调用时只有一个输入参数的值发生变化时，可以大大减少代码量。 |
|
5. 同时具有返回值、输入参数、输出参数的存储过程
前面说过，在调用存储过程时，声明参数的顺序要与存储过程中定义的顺序相同。还有一点要特别注意：如果存储过程同时具有返回值以及输入、输出参数，返回值要最先声明。
为了演示这种情况下的调用方法，我们改善一下上面的例子。还是取得ID为1的用户的用户名，但是有可能该用户不存在(该用户已删除，而userid是自增长的字段)。存储过程根据用户存在与否，返回不同的值。此时，存储过程和ASP代码如下：
/*SP5*/
CREATE PROCEDURE dbo.getUserName
--为了加深对"顺序"的印象，将以下两参数的定义顺序颠倒一下
@UserName varchar(40) output,
@UserID int
as
set nocount on
begin
if @UserID is null return
select @UserName=username
from dbo.[userinfo]
where userid=@UserID
if rowcount> 0
return 1
else
return 0
return
end
go
’**调用同时具有返回值、输入参数、输出参数的存储过程**
DIM MyComm,UserID,UserName
UserID = 1
Set MyComm = Server.CreateObject("ADODB.Command")
with MyComm
.ActiveConnection = MyConStr ’MyConStr是数据库连接字串
.CommandText = "getUserName" ’指定存储过程名
.CommandType = 4 ’表明这是一个存储过程
.Prepared = true ’要求将SQL命令先行编译
’返回值要最先被声明
.Parameters.Append .CreateParameter("RETURN",2,4)
’以下两参数的声明顺序也做相应颠倒
.Parameters.append .CreateParameter("@UserName",200,2,40)
.Parameters.append .CreateParameter("@UserID",3,1,4,UserID)
.Execute
end with
if MyComm(0) = 1 then
UserName = MyComm(1)
else
UserName = "该用户不存在"
end if
Set MyComm = Nothing
6. 同时返回参数和记录集的存储过程
有时候，我们需要存储过程同时返回参数和记录集，比如在利用存储过程分页时，要同时返回记录集以及数据总量等参数。以下给出一个进行分页处理的存储过程：
/*SP6*/
CREATE PROCEDURE dbo.getUserList
@iPageCount int OUTPUT, --总页数
@iPage int, --当前页号
@iPageSize int --每页记录数
as
set nocount on
begin
--创建临时表
create table #t (ID int IDENTITY, --自增字段
userid int,
username varchar(40))
--向临时表中写入数据
insert into #t
select userid,username from dbo.[UserInfo]
order by userid
--取得记录总数
declare @iRecordCount int
set @iRecordCount = rowcount
--确定总页数
IF @iRecordCount%@iPageSize=0
SET @iPageCount=CEILING(@iRecordCount/@iPageSize)
ELSE
SET @iPageCount=CEILING(@iRecordCount/@iPageSize)+1
--若请求的页号大于总页数，则显示最后一页
IF @iPage > @iPageCount
SELECT @iPage = @iPageCount
--确定当前页的始末记录
DECLARE @iStart int --start record
DECLARE @iEnd int --end record
SELECT @iStart = (@iPage - 1) * @iPageSize
SELECT @iEnd = @iStart + @iPageSize + 1
--取当前页记录
select * from #t where ID> @iStart and ID <@iEnd
--删除临时表
DROP TABLE #t
--返回记录总数
return @iRecordCount
end
go
在上面的存储过程中，输入当前页号及每页记录数，返回当前页的记录集，总页数及记录总数。为了更具典型性，将记录总数以返回值的形式返回。以下是调用该存储过程的ASP代码(具体的分页操作略去):
’**调用分页存储过程**
DIM pagenow,pagesize,pagecount,recordcount
DIM MyComm,MyRst
pagenow = Request("pn")
’自定义函数用于验证自然数
if CheckNar(pagenow) = false then pagenow = 1
pagesize = 20
Set MyComm = Server.CreateObject("ADODB.Command")
with MyComm
.ActiveConnection = MyConStr ’MyConStr是数据库连接字串
.CommandText = "getUserList" ’指定存储过程名
.CommandType = 4 ’表明这是一个存储过程
.Prepared = true ’要求将SQL命令先行编译
’返回值(记录总量)
.Parameters.Append .CreateParameter("RETURN",2,4)
’出参(总页数)
.Parameters.Append .CreateParameter("@iPageCount",3,2)
’入参(当前页号)
.Parameters.append .CreateParameter("@iPage",3,1,4,pagenow)
’入参(每页记录数)
.Parameters.append .CreateParameter("@iPageSize",3,1,4,pagesize)
Set MyRst = .Execute
end with
if MyRst.state = 0 then ’未取到数据，MyRst关闭
recordcount = -1
else
MyRst.close ’注意：若要取得参数值，需先关闭记录集对象
recordcount = MyComm(0)
pagecount = MyComm(1)
if cint(pagenow)> =cint(pagecount) then pagenow=pagecount
end if
Set MyComm = Nothing
’以下显示记录
if recordcount = 0 then
Response.Write "无记录"
elseif recordcount > 0 then
MyRst.open
do until MyRst.EOF
......
loop
’以下显示分页信息
......
else ’recordcount=-1
Response.Write "参数错误"
end if
对于以上代码，只有一点需要说明：同时返回记录集和参数时，若要取得参数，需先将记录集关闭，使用记录集时再将其打开。
7. 返回多个记录集的存储过程
本文最先介绍的是返回记录集的存储过程。有时候，需要一个存储过程返回多个记录集，在ASP中，如何同时取得这些记录集呢？为了说明这一问题，在userinfo表中增加两个字段：usertel及usermail，并设定只有登录用户可以查看这两项内容。
/*SP7*/
CREATE PROCEDURE dbo.getUserInfo
@userid int,
@checklogin bit
as
set nocount on
begin
if @userid is null or @checklogin is null return
select username
from dbo.[usrinfo]
where userid=@userid
--若为登录用户，取usertel及usermail
if @checklogin=1
select usertel,usermail
from dbo.[userinfo]
where userid=@userid
return
end
go
以下是ASP代码：
’**调用返回多个记录集的存储过程**
DIM checklg,UserID,UserName,UserTel,UserMail
DIM MyComm,MyRst
UserID = 1
’checklogin()为自定义函数，判断访问者是否登录
checklg = checklogin()
Set MyComm = Server.CreateObject("ADODB.Command")
with MyComm
.ActiveConnection = MyConStr ’MyConStr是数据库连接字串
.CommandText = "getUserInfo" ’指定存储过程名
.CommandType = 4 ’表明这是一个存储过程
.Prepared = true ’要求将SQL命令先行编译
.Parameters.append .CreateParameter("@userid",3,1,4,UserID)
.Parameters.append .CreateParameter("@checklogin",11,1,1,checklg)
Set MyRst = .Execute
end with
Set MyComm = Nothing
’从第一个记录集中取值
UserName = MyRst(0)
’从第二个记录集中取值
if not MyRst is Nothing then
Set MyRst = MyRst.NextRecordset()
UserTel = MyRst(0)
UserMail = MyRst(1)
end if
Set MyRst = Nothing
以上代码中，利用Recordset对象的NextRecordset方法，取得了存储过程返回的多个记录集。
至此，针对ASP调用存储过程的各种情况，本文已做了较为全面的说明。最后说一下在一个ASP程序中，调用多个存储过程的不同方法。
在一个ASP程序中，调用多个存储过程至少有以下三种方法是可行的：
1. 创建多个Command对象
DIM MyComm
Set MyComm = Server.CreateObject("ADODB.Command")
’调用存储过程一
......
Set MyComm = Nothing
Set MyComm = Server.CreateObject("ADODB.Command")
’调用存储过程二
......
Set MyComm = Nothing
......
2. 只创建一个Command对象，结束一次调用时，清除其参数
DIM MyComm
Set MyComm = Server.CreateObject("ADODB.Command")
’调用存储过程一
.....
’清除参数(假设有三个参数)
MyComm.Parameters.delete 2
MyComm.Parameters.delete 1
MyComm.Parameters.delete 0
’调用存储过程二并清除参数
......
Set MyComm = Nothing
此时要注意：清除参数的顺序与参数声明的顺序相反，原因嘛，我也不知道。
3. 利用Parameters数据集合的Refresh方法重置Parameter对象
DIM MyComm
Set MyComm = Server.CreateObject("ADODB.Command")
’调用存储过程一
.....
’重置Parameters数据集合中包含的所有Parameter对象
MyComm.Parameters.Refresh
’调用存储过程二
.....
Set MyComm = Nothing
一般认为，重复创建对象是效率较低的一种方法，但是经测试(测试工具为Microsoft Application Center Test)，结果出人意料：
方法2 > = 方法1 > > 方法3
方法2的运行速度大于等于方法1(最多可高4%左右)，这两种方法的运行速度远大于方法3(最多竟高达130%)，所以建议在参数多时，采用方法1，在参数较少时，采用方法2 |
|
收 藏
投 稿
繁 体
RSS 
欢迎在本站发布信息，在线投递稿件
我要投稿
打印本文
推荐本文
加入收藏
返回顶部
关闭窗口
